ジョイスティックマウス

Arduinoとジョイスティックで、マウスが作れるらしいので作ってみる。スケッチ例だけだと自分の環境では動かなかったので、一個ずつやってみる。

お買い物

http://akizukidenshi.com/catalog/g/gM-08763/

センタープッシュが付いてるやつにした。

接続

つないだ。

とりあえずanalogRead()で取得

int axisX = 0;
int axisY = 0;

void setup() {
  pinMode(18,INPUT);
  pinMode(19,INPUT);

  Serial.begin(9600);
}

void loop() {
  axisX = analogRead(18);
  axisY = analogRead(19);
  Serial.print("X: ");
  Serial.print(axisX);
  Serial.print("   Y: ");
  Serial.print(axisY);
  Serial.println();
}

analogRead()は基準電圧間を10bit(0-1023)のデジタルデータに変換してくれる。静止状態だと、中央値の511-512になるはずなので、この結果はちょっとずれてる。キャリブレーションが必要だけど、まぁ無視する。

Mouse.hを使ってみる

#include <Mouse.h>

boolean finished = false;

void setup() {
  Mouse.begin();

}

void loop() {
  if (!finished) {
    for (int i = 1 ; i <= 10; i++) {
      Mouse.move(-10, 10, 0);
      delay(1000);
      finished = true;
    }
  }
}

止まらなくなるのが怖いので、一旦何回かやったら止まるようにする。Mouse.move()の意味がよく分かってなかったのだけど、現在の位置から、引数の分だけマウスが飛ぶ感じの動きみたい。引数を大きくすれば飛ぶ量が大きくなる。スイーっと動くんじゃなくて、飛ぶ。

2つを合わせてみる

#include <Mouse.h>

boolean finished = false;
int axisX = 0;
int axisY = 0;
signed char X;
signed char Y;

void setup() {
  pinMode(18, INPUT);
  pinMode(19, INPUT);

  Mouse.begin();
}

void loop() {

  if (!finished) {
    for (int i = 1 ; i <= 10000; i++) {
      axisX = analogRead(18);
      axisY = analogRead(19);
      X = map(axisX, 0, 1023, -3, 3);
      Y = map(axisY, 0, 1023, -3, 3);

      Mouse.move(X, Y, 0);
      delay(2);
      finished = true;
    }
  }
}

取りあえず動くものを書いてみた。これだけでも既にカーソルが動いてくれる。すげーな。ただ静止状態でもカーソルが動いてしまうし、動きはカクカクしていてなめらか～な感じじゃない。XY軸沿いの動きはするんだけど、斜めになるととたんに反応が悪くなる。なんだろなー。

map()

https://www.arduino.cc/reference/en/language/functions/math/map/

https://qiita.com/QUANON/items/188baf469fd493a2f1e6

これ便利ね。

参考

https://www.arduino.cc/reference/en/language/functions/usb/mouse/

モールス信号

モールス信号を復号したい。誰かから送られてきたやつじゃなくて、自分が入力したやつを復号したい。

スイッチを押下・離上間の時間を取得

unsigned long starttime = 0;
unsigned long endtime = 0;
unsigned long diff = 0;

void setup() {
  pinMode(9, INPUT_PULLUP);
  Serial.begin(9600);
}

void loop() {

  if (digitalRead(9) == LOW) {
    starttime = millis();
    
    while (digitalRead(9) == LOW) {}
    
    endtime = millis();
    diff = endtime - starttime;
    
    Serial.print(diff);
    Serial.println();
    delay(10);
  }
}

とりあえず時間が取れた。

閾値を設定して短点と長点を判断

#define threshold 200

unsigned long starttime = 0;
unsigned long endtime = 0;
unsigned long diff = 0;

void setup() {
  pinMode(9, INPUT_PULLUP);
  Serial.begin(9600);
}

void loop() {

  if (digitalRead(9) == LOW) {
    starttime = millis();
    while (digitalRead(9) == LOW) {}
    endtime = millis();
    diff = endtime - starttime;

    if (diff < threshold) {
      Serial.print("・");
      Serial.println();
    } else {
      Serial.print("－");
      Serial.println();
    }

    delay(10);
  }
}

判断もできた。こっからだなぁ。

閾値を設定して文字の区切りを取得

#define thresholdsl 200
#define thresholdchr 400

unsigned long starttime = 0;
unsigned long endtime = 0;
unsigned long diff = 0;
boolean duringinput = false;
boolean decrypted = true;

void setup() {
  pinMode(9, INPUT_PULLUP);
  Serial.begin(9600);
}

String decisl(unsigned long t) {
  if (t < thresholdsl) {
    return "・";
  }
  return "－";
}

void loop() {

  if (digitalRead(9) == LOW) {
    starttime = millis();
    
    if (!duringinput) {
      duringinput = true;
      decrypted = false;
    }

    while (digitalRead(9) == LOW) {}
    endtime = millis();
    diff = endtime - starttime;

    Serial.print(decisl(diff));
    Serial.println();
    delay(10);
  }

  if ( (millis() - endtime) > thresholdchr && !decrypted) {
    Serial.print("result");
    Serial.println();
    duringinput = false;
    decrypted = true;
  }
  
}

行き当たりばったりで書いていったらこうなった。もう一回作れと言われると作れなさそう。できるだけ残そ。

短点2つの場合、

うーん、上手く書けない。こんな感じで遷移してるはず。あとはresultを、入力から対応する文字に復号した結果を表示させるようにすればいいはず。

入力値から復号

Arduinoには、key-value形式で扱えるような、DictionaryとかHashMapみたいなものがない、らしい。探したけど見つかんなかった。「・－」→「A」みたいなデータの引っ張り方はできないってことなのでなにか考えないといかん。最悪switchで愚直に全部書く方法があるけど、それはやだなって思ったので、とりあえず「・」→「0」、「ー」→「1」として、それをkeyにしてデータ引っ張れないかを試してみることにする。

最初考えたのはバイナリ化した符号を10進にして、それを配列の添字にしてあげればデータを引っ張れるんじゃないかと思った。でも、10進数にすると重複が発生してしまい、よろしくなかった。なんかないかなーとネットの海を彷徨っていたら、16bitのデータ長で上位12bit(実際に使われるのは6bit)を短長点、下位4bit(実際に使われるのは3bit)を符号長として表すやり方をみつけた。これでいけそうな気がする。で、2分木として扱えばよさげだなーと思ったので、添字を計算した。でも、なんか記号のプログラムのソースコード上での扱い方がわかんなかったので、上表の9までにしか対応ないことにした。

morsetable.h

const String mtable[] = {
  "", "E", "T", "I", "A", "N", "M", "S", "U", "R", "W", "D", "K", "G", "O", "H", "V", "F", "", "L", "", "P", "J", "B", "X", "C", "Y", "Z", "Q", "", "", "5", "4", "", "3", "", "", "", "2", "", "", "", "", "", "", "", "1", "6", "", "", "", "", "", "", "", "7", "", "", "", "8", "", "9", "0"
};

morse

#include "morsetable.h"

#define pin 9
#define tlsl 200
#define tlchr 400

unsigned long starttime = 0;
unsigned long endtime = 0;
unsigned long diff = 0;
boolean duringinput = false;
boolean decrypted = true;
byte mrsbin [] = {0b0, 0b0};

void setup() {
  pinMode(pin, INPUT_PULLUP);
  Serial.begin(9600);
}

void decisl(unsigned long t) {
  mrsbin[0] = mrsbin[0] << 1;

  if (t > tlsl) {
    mrsbin[0] = mrsbin[0] + 1;
  } else {
    mrsbin[0] = mrsbin[0] + 0;
  }

  mrsbin[1] = mrsbin[1] + 1;
}

int mrstblidx (byte b[]) {
  byte msb = 0b0;
  int idx = 0;

  for (int i = 1; i <= (int)b[1]; i++) {
    msb = ((b[0] << (8 - (int)b[1]) + i - 1) & 0b10000000) >> (8 - i);

    if (msb == 0) {
      idx = 2 * idx + 1;
    } else {
      idx = 2 * idx + 2;
    }
  }
  return idx;
}

void loop() {

  if (digitalRead(pin) == LOW) {
    starttime = millis();

    if (!duringinput) {
      duringinput = true;
      decrypted = false;
    }

    while (digitalRead(pin) == LOW) {}
    endtime = millis();
    diff = endtime - starttime;
    decisl(diff);

    //    Serial.print(mrsbin[0]);
    //    Serial.print(mrsbin[1]);
    //    Serial.println();
    delay(10);
  }

  if ( (millis() - endtime) > tlchr && !decrypted) {
    Serial.print(mtable[mrstblidx(mrsbin)]);
    Serial.println();
    duringinput = false;
    decrypted = true;
    mrsbin [0] = 0;
    mrsbin [1] = 0;
  }

}

こんな感じになった。MSB取り出すところがちょっと気持ち悪いなー。

いー感じだ!ただまぁ、短長点の手癖には対応できてないので機械に人間が合わせる感じになるかな。

参考

https://ja.wikipedia.org/wiki/%E3%83%A2%E3%83%BC%E3%83%AB%E3%82%B9%E7%AC%A6%E5%8F%B7

http://www.kyohritsu.jp/eclib/DIGIT/KIT/morsejamp.pdf

http://machoto2.g2.xrea.com/page/P14K50/P14_B17.htm

https://ja.wikipedia.org/wiki/%E4%BA%8C%E5%88%86%E6%9C%A8

https://cpprefjp.github.io/lang/cpp14/binary_literals.html

http://www.musashinodenpa.com/arduino/ref/index.php?f=0&pos=665

http://www.musashinodenpa.com/arduino/ref/index.php?f=0&pos=784

スイッチ

スイッチを押すとカウントが増えるやつ。

とりあえずやる

こんな感じでつなぎ

int count = 0;

void setup() {
  pinMode(9, INPUT_PULLUP);
  Serial.begin(9600);
}

void loop() {

  if (digitalRead(9) == LOW) {
    count++;
    Serial.print(count);
    Serial.println();
  }
}

こんなコードを書き 、スイッチをポチッと押すと

12:09:51.333 -> 1
12:09:51.333 -> 2
12:09:51.333 -> 3
～略～
12:09:51.437 -> 757
12:09:51.437 -> 758
12:09:51.437 -> 759

値がすっ飛ぶ。スイッチを離すまでに、次のloopが来てしまうからこういうことになるみたい。(cf.チャタリング)。よろしくないので適当に遅延を入れる。

遅延入れる

int count = 0;

void setup() {
  pinMode(9, INPUT_PULLUP);
  Serial.begin(9600);
}

void loop() {

  if (digitalRead(9) == LOW) {
    count++;
    Serial.print(count);
    Serial.println();
    delay(200);
  }
}

そうするとまぁ

12:41:46.180 -> 1
12:41:47.033 -> 2
12:41:47.924 -> 3
12:41:48.836 -> 4
12:41:49.723 -> 5

ポチッぐらいだと上手くいく。これがポーッチとかﾎﾟﾁﾎﾟﾁﾎﾟﾁとかだと押した回数とカウントが一致しない。

こんな。ポーッチとかﾎﾟﾁﾎﾟﾁﾎﾟﾁとかにも対応したい。

ボタンを離すとカウントアップ

int count = 0;

void setup() {
  pinMode(9, INPUT_PULLUP);
  Serial.begin(9600);
}

void loop() {

  if (digitalRead(9) == LOW) {
    while (digitalRead(9) == LOW) {}
    
    count++;
    
    Serial.print(count);
    Serial.println();
    delay(10);
  }
}

押したときではなく、離した時にカウントすればいいのではと考えた。コード的に合ってるか微妙なとこだけどこう書いた。何もしないループって作っていいのかな。微妙にチャタるのでdelayも入れてみてる。

いい感じでは。

ブザー

音が出る。電気流すだけでできるみたい。

お買い物

http://akizukidenshi.com/catalog/g/gP-09800/

こちらを買いまして。定格5Vなので何も考えずにに繋げば良さそう。

http://akizukidenshi.com/catalog/g/gP-03647/

あとスイッチ。押すと繋がって、離すと切れる。

接続して手動で鳴らす

ブザーには極性があった。Arduino5V→スイッチ→ブザー→ArduinoGNDてつないでみた。

押すと鳴る。でもこれはあんまりよろしくないみたい。スイッチオフのときが、浮いてる状態だから?なの?

プルアップ・プルダウン

詳しくは

https://voltechno.com/blog/pullup-pulldown/

や

https://slash-mochi.net/?p=978

で、リファレンスは

https://www.arduino.cc/reference/en/language/functions/digital-io/pinmode/

とか

https://www.arduino.cc/en/Tutorial/DigitalPins

などを参考にいたしまして、色々試してみたものの、理解が追いつかず、とりあえずこれでいいやと思いました。

プログラムで鳴らす

こんな感じで、D01(9)ピン→ブザー→GNDで接続して

void setup() {
  pinMode(9, OUTPUT);
}

void loop() {

  for (int i = 1; i <= 3; i++) {
    digitalWrite(9, HIGH);
    delay(100);
    digitalWrite(9, LOW);
    delay(100);
  }

  delay(300);

  for (int i = 1; i <= 3; i++) {
    digitalWrite(9, HIGH);
    delay(300);
    digitalWrite(9, LOW);
    delay(100);
  }

  delay(300);

  for (int i = 1; i <= 3; i++) {
    digitalWrite(9, HIGH);
    delay(100);
    digitalWrite(9, LOW);
    delay(100);
  }

  delay(700);

}

こんな感じのコードを書きまして、カウンタ一緒だけどいいのかな。

すると鳴ります。SOS!。

toneを使う

void setup() {
  pinMode(9, OUTPUT);
}

void loop() {

  for (int i = 32; i <= 8000; i++) {
    tone(9, i);
    delay(10);
    noTone(9);
  }
}

toneを使うと音階が作れる。

スケッチ例のtoneMelodyをやると

動画だと微妙だけど、ちゃんと聞こえる。すげー。